TI83 computing LeftSum

METHOD 0 A program suggested by the textbook. This uses y1 for the function

PROGRAM RSUMS
:Disp "LOWER LIMIT"
:Input A
:Disp "UPPER LIMIT"
:Input B
:Disp "DIVS"
:Input N
:A->X
:0->S
:1->I
:(B-A)/N->H
:Lbl P
:S+H*Y1->S           ***** Y1 is via the vars menu and not just typed Y1
:X+H->X
:IS>(I,N)
:Goto P
:Disp "LEFT SUM"
:Disp S
:S+Y1*H->S
:A->X
:S-Y1*H->S
:Disp "RIGHT SUM"
:Disp S

Test data y1=x^3, a=1, b=3, n=100 gives Left sum 19.7408 and right sum
of 20.2608

METHOD 1 programming LEFTSUM

We want to compute the Leftsum of integral from a to b of f(x) with n
subdivisions.

We want to do
set t to 0
for i = 0 to n-1 (in steps of 1) do
	set x to be a + i*(b-a)/n
	set t to be the old value of t + the value of f(x)
end_for_loop
now t contains the leftsum
[For the right sum i would go from 1 to n instead of the 0 to n-1 for leftsum.]

We will do this in two steps:
1. program FUN will take whatever is in the x storage location do f(x)
and store the result in the f storage location. So if f(x) = sin(x^2)
Program Fun looks like
PROGRAM:FUN
:sin(X^2)->F

2. program LEFTSUM will do the loop calling program FUN to function
evaluation.
PROGRAM:LEFTSUM
:Prompt N,A,B
:0->T
:For(I,0,N-1)
:A+I(B-A)/N->X
:prgmFUN
:T+F(B-A)/N->T
:End
:Disp "SUM IS",T

METHOD 2 do it on the command line.
Enter the following on a regular line. The sum is #5 on the MATH submenu
of the LIST menu. The seq is #5 on the OPS submenu of the LIST menu. Note
that this can get messy if "x" occurs oftem in f(x) say like x^3+x^2+x.

100->N:1->A:3->B:sum(seq(sin((A+I(B-A)/N)^2),I,0,N-1)(B-A)/N)