# $Source: /u/maple/research/lib/algcurves/src/RCS/genus,v $
# $Notify: mvanhoei@daisy.uwaterloo.ca $

macro(
	RAD={radical,nonreal},
	genus=`algcurves/genus`
):

# f is a polynomial in x and y
genus:=proc(f,x::name,y::name)
	local F,d,X,Y,i;
	options remember, 
`Copyright (c) 1996 Waterloo Maple Inc. All rights reserved. Author: M. van Hoeij`;
if nargs>3 and args[nargs]=`irr check` then
	F:=evala(AFactors(f));
	if nops(F[2])>1 or F[2][1][2]>1 then
		args[1],"factored as",F
	else
		procname(f,x,y)
	fi
elif not type(f,polynom(anything,[x,y])) then
	error "wrong type of arguments"
elif indets(f,RAD)<>{} then
	procname(subs(radfield(f)[1],f),x,y)
else
	# The following is to ensure that degree(..) gives the right answer.
	Normalizer:=`if`(has(f,RootOf),`evala/Normal`,normal);
	F:=collect(primpart(f,{x,y}),{x,y},'distributed',Normalizer);
	d,X,Y:=degree(F,{x,y}),degree(F,x),degree(F,y);
	i:=d-ldegree(F,{x,y});
	if d<1 then
		error "degree is zero"
	elif d>1 and (i=0 or X*Y<1 or
	has(evala(Content(f,x)),y) or has(evala(Content(f,y)),x)) then
		WARNING( "curve failed simple reducibility test, returning -1" );
		-1
	elif d=2 or X=1 or Y=1 or i=1 then
		0
	elif Y>2 and i=2 then
		procname(subs(y=1,`algcurves/homogeneous`(F,x,y,z)),x,z)
	elif Y>2 and (X=2 or X+degree(lcoeff(F,x),y)
			    <Y+degree(lcoeff(F,y),x)) then
		# Switching x and y is not strictly necessary, but speeds up
		# the computation.
		procname(F,y,x)
	else
	    if Y=2 then
		# We could call `algcurves/singularities` but the following is
		# likely to be faster:
		F:=Normalizer(discrim(F,y));
		if F=0 then error "Input should be squarefree" fi;
		# Take the factors with odd multiplicity
		X:=floor((add(irem(i[2],2)*degree(i[1],x),
		 i=sqrfree(F,x)[2])-1)/2)
	    elif F=(subs(x=0,F)-subs(x=0,y=0,F))+subs(y=0,F) then
		# For this case there is an efficient way:
		X:=`algcurves/genus_fx_plus_gy`(
		 subs(y=0,F),subs(x=0,F)-subs(x=0,y=0,F),x,y)
	    else
		X:=(d-1)*(d-2)/2-add(i[3]*`algcurves/degree_ext`(i,F),i=
		 `algcurves/singularities`(F,x,y))
	    fi;
	    if X<0 then
		WARNING( "negative genus so the curve is reducible" )
	    fi;
		X
	fi
fi
end:

#savelib('genus'):